ASP: HTTP 500.100 hatalarına hükmedin

ASP´de oluşan hataları Server nesnesinin GetLastError alt nesnesiyle öğrenebiliyoruz. GetLastError nesnesinin özelliklerine kısaca değinecek olursak:

ASPCode: IIS tarafından oluşturulan hata kodunu döndürür.
ASPDescription: Oluşan hata ASP ile alakalıysa detaylı bir açıklama döndürür.
Category: Hatanın kaynağını döndürür.
Column: ASP sayfası içinde hataya sebep olan kodlamanın sütun pozisyonunu döndürür.
Description: Hata hakkında kısa bir açıklama döndürür.
File: Hata oluşan ASP dosyasının yolunu döndürür.
Line: Hatanın kaçıncı satırda oluştuğunu döndürür.
Number: Standart COM hata numarası döndürür.
Source: Hataya sebep olan kodlar okunabiliyorsa bu kodları döndürür.
Bu yazının amacı, bu nesneyi kullanarak oluşan hataları bir veritabanında depolamak ve ziyaretçinin uyarısına gerek kalmadan, anında hatadan haberdar olup müdahale edebilmeyi göstermektir. Madem veritabanına kaydedeceğiz, bir tane oluşturalım. Aşağıda hem MS Access için hem de MySQL için birer örnek bulunuyor:

MS Access Örneği
<%
Dim Katalog, Bag
Set Katalog = Server.CreateObject("ADOX.Catalog")
Set Bag = Server.CreateObject("ADODB.Connection")

´ Veritabanını oluşturuyoruz
Katalog.Create "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:Hata.mdb"
´ ve bu veritabanına bağlanıyoruz
Bag.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=C:Hata.mdb"

´ tablomuzu oluşturuyoruz
SQL = "CREATE TABLE tblHata (" &_
"fldID COUNTER PRIMARY KEY, " &_
"fldASPCode INTEGER, " &_
"fldASPDescription CHAR(255), " &_
"fldCategory CHAR(50), " &_
"fldColumn INTEGER, " &_
"fldDescription CHAR(255), " &_
"fldFile CHAR(100), " &_
"fldLine INTEGER, " &_
"fldNumber INTEGER, " &_
"fldSource CHAR(255), " &_
"fldHit INTEGER, " &_
"fldDuzenleme BIT" &_
")"

´ ve bunu veritabanına ekliyoruz
Set Olustur = Bag.Execute(SQL)
´bitti
Response.Write "Veritabanı C: dizininde oluşturuldu!"
%>


MySQL Örneği
CREATE TABLE `tblhata` (
`fldID` int(11) NOT NULL auto_increment,
`fldASPCode` int(11) default NULL,
`fldASPDescription` char(255) default NULL,
`fldCategory` char(50) default NULL,
`fldColumn` int(11) default NULL,
`fldDescription` char(255) default NULL,
`fldFile` char(100) default NULL,
`fldLine` int(11) default NULL,
`fldNumber` int(11) default NULL,
`fldSource` char(255) default NULL,
`fldHit` int(1) default NULL,
`fldDuzenleme` bit(1) default NULL,
PRIMARY KEY (`fldID`)
) ENGINE=MyISAM DEFAULT CHARSET=latin1;
MS Access örneğindeki kodu komple kopyalayıp çalıştırısanız C: dizininde Hata.mdb isimli dosya oluşturulur ve kullanmanız için sizi bekler. MySQL için ise, kodu kopyalayıp MySQL Query Browser veya muadili programları kullanarak veritabanınızı oluşturabilirsiniz. Ben her ne kadar MySQL kullansam da örneğimi MS Access üzerinden vereceğim. İsteyen gerekli değişiklikleri yaparak kodu istediği veritabanına çevirebilir.

Veritabanımız hazırsa artık kodlamaya geçebiliriz. Burada uygulayacağımız örnek orjinal dokümandaki sevimsizliği anımsatsa da hayal gücünüzü kullanarak tasarımınızla bunun üstesinden gelebilirsiniz

hata.asp
<%
´ Normal Değişkenler
Dim ASPKodu, ASPAciklama, Kategori, Sutun, Aciklama, Dosya, Satir, Numara, Kaynak
´ Nesneler
Dim Hata, Kontol, Bag, Ekle, Guncelle
´ Mesajların içindeki tek ve çift tırnakları temizleyen fonksiyon
Function Temizle(Metin)
Metin = Replace(Metin,"""",""")
Metin = Replace(Metin,"´","'")
Metin = Replace(Metin,"","\")
Temizle = Metin
End Function

´ Hata veritabanımıza bağlanıyoruz
Set Bag = Server.CreateObject("ADODB.Connection")
Bag.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=C:Hata.mdb"

´ Hatayı öğreniyoruz
Set Hata = Server.GetLastError()

´ Hata içeriğini değişkenlerimize aktarıyoruz
With Hata
ASPKodu = Temizle(.ASPCode)
ASPAciklama = Temizle(.ASPDescription)
Kategori = Temizle(.Category)
Sutun = Temizle(.Column)
Aciklama = Temizle(.Description)
´ Dosya kısmını biraz genişleterek hangi siteye ait olduğunu da yazdıralım
´ Bu sayede kodu kök düzün altına atarsak sitelere göre ayırmak daha kolay olur.
Dosya = Temizle("http://" & Request.ServerVariables("SERVER_NAME") & .File)
Satir = Temizle(.Line)
Numara = Temizle(.Number)
Kaynak = Temizle(.Source)
End With

´ Değişkenler veritabanına kaydedilirken hata almayalım diye varsayılanları ayarlayalım.
´ Sonra hata sayfasında hata verdirip madara olmayalım
If ASPKodu = "" Then ASPKodu = 0
If Sutun = "" Then Sutun = 0
If Satir = "" Then Satir = 0
If Numara = "" Then Numara = 0

´ Daha önceden bu hata mesajı veritabanımıza kaydedilmiş mi?
Set Kontrol = Bag.Execute("SELECT fldFile, fldDescription, fldNumber FROM tblHata WHERE fldFile=´" & Dosya & "´ AND fldDescription=´" & Aciklama & "´ AND fldNumber=" & Numara)

´Kaydedilmemişse edelim, edilmişse hatayla kaç kere karşılaşılmış not edelim
If Kontrol.EOF Then
Set Ekle = Bag.Execute("INSERT INTO tblHata(fldASPCode, fldASPDescription, fldCategory, fldColumn, fldDescription, fldFile, fldLine, fldNumber, fldSource, fldHit, fldDuzenleme) VALUES(" & ASPKodu & ",´" & ASPAciklama & "´,´" & Kategori & "´," & Sutun & ",´" & Aciklama & "´,´" & Dosya & "´," & Satir & "," & Numara & ",´" & Kaynak & "´,1,False)")
Else
Set Guncelle = Bag.Execute("UPDATE tblHata Set fldHit=fldHit+1 WHERE fldFile=´" & Dosya & "´ AND fldDescription=´" & Aciklama & "´ AND fldNumber=" & Numara)
End If
%>
<html>
<head>
<title>Hata oluştu!</title>
<META HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=ISO-8859-9">
</head>
<body>
<h3 style="color:#FF0000">Sayfa kodları işlenirken hata oluştu!</h3></center><p>
<% If ASPKodu <> 0 Then Response.Write "<b>Hatanın ASP Kodu</b>: 0x" & ASPKodu & "<br>" %>
<% If ASPAciklama > "" Then Response.Write "<b>Hatanın ASP Açıklaması</b>: " & ASPAciklama & "<br>" %>
<% If Kategori > "" Then Response.Write "<b>Hata Kategorisi</b>: " & Kategori & "<br>" %>
<% If Sutun <> "-1" Then Response.Write "<b>Hatanın oluştuğu Sütun</b>: " & Sutun & "<br>" %>
<% If Aciklama > "" Then Response.Write "<b>Hatanın Açıklaması</b>: " & Aciklama & "<br>" %>
<% If Dosya > "" Then Response.Write "<b>Hata oluşan Dosya</b>: " & Dosya & "<br>" %>
<% If Numara > "" Then Response.Write "<b>Hata Numarası</b>: " & Numara & "<br>" %>
<% If Satir > "" Then Response.Write "<b>Hataya Sebep Olan Satır</b>: " & Satir & "<br>" %>
<% If Kaynak > "" Then Response.Write "<b>Hatanın Kaynağı</b>: " & Kaynak & "<br>" %><br>
<b style="color:#FF0000">Hataya sebebiyet veren kodlar kaydedildi ve en kısa zamanda düzeltilecektir.<br>Oluşan bu hatadan dolayı özür dileriz...</b><p>
</body>
</html>

Kodumuzun ne yaptığına kısaca değinecek olursak; Hata.mdb´ye bağlanıyor, hata kodlarını öğreniyor, eğer hata kodu daha önceden veritabanımıza kaydedilmemişse yeni hata kaydı olarak ekliyor, yok eklenmişse hit değerini arttırıp o hatayla kaç kere karşılaşıldığının kaydını tutuyor, son olarakta kullanıcıya bilgilendirici bir mesaj ulaştırıyor. (Sanki kullanıcı bu yazılanlardan birşey anlayacak )

Özelleştirdiğimiz hata sayfamız tamam. Şimdi sıra bu hata sayfasını IIS ile tanıştırmakta. Ben örneklerimi localhost üzerinden vereceğim. Başlat > Ayarlar > Denetim Masası > Yönetimsel Araçlar menüsünden Internet Information Server (IIS)´i çalıştırın. XX (yerel bilgisayar) > Web Siteleri > Varsayılan Web Sitesi ağacını açın. (Buradaki XX kendi bilgisayarınızın adı.) Dilerseniz bundan sonraki işlemi -varsa- sanal dizinler için uygulayabilirsiniz. Bu yazıda tüm işlemler Varsayılan Web Sitesi altında gerçekleştirilecektir.

Varsayılan Web Sitesi´ne sağ tıklayıp açılan menüden Özellikleri´i seçin.
Ekrana gelen penceredeki Özel Hatalar tabına tıklayın ve listeden HTTP Hatası başlığı altında bulunan 500;100´ü seçip aktif olan Özellikleri Düzenle butonuna tıklayın.
İleti Türü olarak URL´yi seçin ve aşağıda beliren URL kutucuğuna /hata.asp yazın. (Tabi bu durumda hata.asp´nin, kök dizinde bulunması gerekir. Varsayılan kök dizin C:inetpubwwwroot´tur.)
Bundan sonra tüm pencereler kapanana kadar gördüğünüz bütün Tamam butonlarına tıklayın.
Hata sayfamızı IIS´ye de tanıttığımıza göre de bir deneme yapalım değil mi? Bu yeni kullanıcılar için kolay olsa da ben tecrübeli kullanıcılar için basit bir hatalı sayfa oluşturayım dedim

hatalisayfa.asp
<% Err.raise(21) ´ 21 uğurlu rakamımdır da... %>